use "http://www.learneconometrics.com/data/stata/SeatBelts.dta", clear
xtset fips year, yearly

gen ln_inc=log(income)
regress  fatalityrate  sb_useage speed65 speed70 ba08 drinkage21 ln_inc age, vce(hc3)

/* One sided t-test on the sb_useage coefficient is 
   not rejected at the 5% level.  It actually has the
   wrong sign.  */

xtreg fatalityrate sb_useage speed65 speed70 ba08 drinkage21 ln_inc age, fe vce(cluster fips)
xi:  regress  fatalityrate  sb_useage speed65 speed70 ba08 drinkage21 ln_inc age i.state, vce(cluster fips)  
/* Note that xtreg and xi do not produce the same results.  They should.  */

xi:  regress  fatalityrate  sb_useage speed65 speed70 ba08 drinkage21 ln_inc age i.state i.year, vce(cluster state) 
testparm _Iyear*
scalar sb_effect = _b[sb_useage]

summarize sb_useage fatalityrate

scalar d_fr = sb_effect*0.38
scalar list d_fr

/* Get the total vehicle miles for 1997
   Here I multiply the average times the number of states */
summarize vmt if year == 1997
scalar miles = 51*r(mean)

scalar lives_saved = miles * d_fr
scalar list lives_saved miles
di "The fatalities change by approximately " lives_saved "
di "Based on an estimated " miles " miles of highway in the US in 1997." 

/* First, run the regression and determine how much sb usage increases
** when switching between secondary to primary enforcement.  Then
** multiply this times the seat belt effect in the fatality rate regression.
*/
xi:  regress sb_useage primary secondary speed65 speed70 ba08 drinkage21 ln_inc age i.year i.state, vce(cluster state)
scalar chg = _b[primary]-_b[secondary]
scalar effect = chg*sb_effect

/*  Finally, get the vehicle miles for NJ in 2000.
**  Since this is not available, I use 1997 data.
**  In 1997 there are about 63300 miles in NJ 
*/
summarize vmt if state == "NJ" & year == 1997
scalar NJ_effect = r(mean)*effect
scalar list chg effect NJ_effect 

di "The switch has a estimated effect of " NJ_effect " on fatalities in New Jersey"