program drop _all
use "http://learneconometrics.com/data/stata/money.dta", clear
/* Prepare the data */
gen New_t = yq(year,qtr) 
tsset New_t, quarterly

drop if year == 1967 & qtr < 4 

reg lm r ly L.lm
predict uhat, resid

/* GNR test of AR(1) */
reg uhat L.uhat r ly L.lm
scalar nr2 = e(N)*e(r2)
scalar pval = chi2tail(1,nr2)
scalar list nr2 pval

/* GNR test of AR(1) replacing first residual with zero */
replace uhat = 0 in 1
reg uhat L.uhat r ly L.lm
scalar nr2 = e(N)*e(r2)
scalar pval = chi2tail(1,nr2)
scalar list nr2 pval

/* NLS Estimation of AR(1) */
nl (lm = (1-{rho})*{b1} + {rho}*L.lm +   (r - {rho}*L.r)*{b2} + (ly - {rho}*L.ly)*{b3} + (L.lm - {rho}*L2.lm)*{b4}) in 3/124   

/* NLS Estimation of AR(2) */
nl (lm = (1-{r1}-{r2})*{b1} + {r1}*L.lm  + {r2}*L2.lm +   (r - {r1}*L.r - {r2}*L2.r)*{b2} + (ly - {r1}*L.ly - {r2}*L2.ly)*{b3} + (L.lm - {r1}*L2.lm - {r2}*L3.lm)*{b4}) in 4/124
 
/* ML Estimation of AR(1) and AR(2) */
arima lm r ly L.lm, ar(1)
arima lm r ly L.lm, ar(1 2)

/* Two step fgls estimation retaining 1st obs */
prais lm r ly L.lm, twostep