* use "C:\data\STATA\participation.dta", clear
use "H:\Documents and Settings\Lee\My Documents\Document\stata\participation.dta", clear

gen A2 = A*A

* Exercise 11.11 std errors from various methods
* The robust option gives you a sandwich
* Best I can tell, bfgs, dfp results are evaluated at Hessian
* So these will be the same as those from nr (if not using robust).

quietly probit lfp I A A2 E nu no F, technique(bfgs) robust
estimates store bfgs
quietly probit lfp I A A2 E nu no F, technique(bhhh) 
estimates store bhhh
quietly probit lfp I A A2 E nu no F, technique(dfp) 
estimates store dfp
quietly probit lfp I A A2 E nu no F, technique(nr) 
estimates store nr
predict index_u, xb

* Using OPG regression to get std errors.  see p. 427 ETM  
generate Ft = normal(index_u)
generate ft = normalden(index_u)

/* variance */
gen vt = Ft*(1-Ft)
/* you may need a constant */
gen one = 1

/* transform variables for OPG regression */
gen ind=(lfp-Ft)*ft/vt
gen Istar=ind*I
gen Astar=ind*A
gen A2star=ind*A2
gen Estar=ind*E
gen nustar=ind*nu
gen nostar=ind*no
gen Fstar=ind*F

/* OPGR */
quietly reg one Istar Astar A2star Estar nustar nostar Fstar ind, noconst 
estimates store opgr_se
estimates table nr bhhh dfp bfgs opgr_se, b(%7.4f) se(%7.4f) equations(1) 
estimates table opgr_se, b(%7.0f) se(%7.4f)